* Ing. Tom Heryán, Ph.D.
** F I N A N Č N Í   E K O N O M E T R I E   S T A T A 
* _________________________________________________________


// I // DATA MANAGEMENT + ZÁKLADNÍ POJMY - REGRESNÍ ANALÝZA


* _________________________________________________________
**# Bookmark #1
// A // Tvorba proměnných + Grafická analýza
clear		// VŽDY vymazat paměť !!!! Text vkládám VŽDY pouze dvě lomítka
import excel "K:\FEC_2025\DATA_akcie.xlsx", sheet("Financni_ekonometrie") firstrow
* NUTNÉ VŽDY upravit červenou adresu a název listu Vašeho soubory s daty

* definování časové řady
tsset Date, daily

* Vytvoření denních výnosů v procentech (NE absolutních hodnotách)
generate RI = IR*100
generate RE = ER*100
generate RA = AR*100
generate RB = BR*100

* Odstranění původních absolutních hodnot
drop IR ER AR BR


* KOMPARACE grafů uzavíracích hodnot
twoway (line IC Date, name(price1, replace))
twoway (line EC Date, name(price2, replace))
twoway (line AC Date, name(price3, replace))
twoway (line BC Date, name(price4, replace))

graph combine price1 price2 price3 price4, title("KOMPARACE") subtitle("Vývoj uzavíracích cen akciového trhu") xsize(80) ysize(100) name(VYVOJ_CENY, replace)
graph export 01graf_vyvoj_cen_stock_market.pdf, as(pdf) replace 















* _________________________________________________________
**# Bookmark #2					POZOR NA ODLEHLÉ, EXTRÉMY !!! (table*replace)
// B // Deskriptivní statistika - odstranění extrémních hodnot
*table ( Date ) ( result ) () if RA>100, statistic(max  RA)
*table ( Date ) ( result ) () if RA<-50, statistic(min  RA)

summarize RA , detail
* Odmazání odlehlých hodnot (smazání extrémů)
replace RA=. if RA>100
replace RA=. if RA<-50
summarize RA , detail


* Normální rozdělení a finanční data ???
histogram RI, bin(10) normal name(histogram1, replace)
histogram RE, bin(10) normal name(histogram2, replace)
histogram RA, bin(10) normal name(histogram3, replace)
histogram RB, bin(10) normal name(histogram4, replace)

graph combine histogram1 histogram2 histogram3 histogram4, title("KOMPARACE") subtitle("Rozdělení dat pro denní výnosy") xsize(80) ysize(100) name(ROZDELENI_VYNOS, replace)
graph export 03graf_rozdělení_denni_vynosy.pdf, as(pdf) replace 



* Shapiro-Wilk test normánlího rozdělení
swilk RI RE RA RB
help swilk



* STACIONARITA ??? (viz níže Bookmark #3)
twoway (line RI Date, name(vol1, replace))
twoway (line RE Date, name(vol2, replace))
twoway (line RA Date, name(vol3, replace))
twoway (line RB Date, name(vol4, replace))

graph combine vol1 vol2 vol3 vol4, ycommon title("KOMPARACE") subtitle("Denní výnos akciového trhu") xsize(80) ysize(100) name(DENNI_VYNOS, replace)
graph export 02graf_volatilita_denni_vynos.pdf, as(pdf) replace 















* _________________________________________________________
**# Bookmark #3
// C // REGRESNÍ ANALÝZA = UMĚT PODMÍNKY TESTOVÁNÍ (ZELENĚ)
 
* Stacionarita
dfuller RE, lags(0)
dfuller RA, lags(0)
dfuller RB, lags(0)
dfuller RI, lags(0)

help dfuller

* Lineární regresní model (metoda OLS, Ordinary Least Squares)
regress RE RA RB RI
estat hettest
estat archlm
estat dwatson

spearman RE RA RB RI, stats(rho obs p) star(0.05)







// I //  M O D E L Y   V O L A T I L I T Y - PODMÍNĚNÁ HETEROSKEDASTICITA !!!


* _________________________________________________________
**# Bookmark #1
// A // Tvorba modelu GARCH

* =====================================
* Treshold-GARCH Modeling
* Ing. Tom Heryán, Ph.D.
* =====================================



* =====================================
// III. // NÍŽE  V Ž D Y  DVA indexy (ESG, trh) + DVĚ Proměnné 
  
* =====================================



// plot the index - reproduce graph IC 
twoway (line IC Date), ///
		xlabel(, format(%tdCCYY)) xtitle("") ylabel(,angle(0)) ytitle("") ///
		name(index, replace) scheme(s2mono)
 
graph export volatility1.pdf, as(pdf) replace 


// plot the percentage RI - reproduce grapg RI
twoway (line RI Date), ///
		xlabel(, format(%tdCCYY)) xtitle("") ylabel(,angle(0)) ytitle("") ///
		name(rets, replace) scheme(s2mono)

graph export "volatility2.pdf", as(pdf) replace 


// plot correlograms - reproduce Figure CORRELOGRAMS
ac RI, lags(20) title("ACF RI", size(medsmall)) ylabel(,angle(0)) ///
			xtitle("Lags") ytitle("Autocorrelations") recast(bar) ///
			fcolor(none)  note("") lcolor(black) lwidth(medthick) name(ac1,replace) scheme(s2mono)			
generate RI2 = RI^2

ac RI2, lags(20) title("ACF squared RI", size(medsmall)) ylabel(,angle(0)) ///
			xtitle("Lags") ytitle("Autocorrelations") recast(bar) ///
			fcolor(none)  note("") lcolor(black) lwidth(medthick) name(ac2,replace) scheme(s2mono)
			
graph combine ac1 ac2, cols(1) imargin(tiny) scheme(s2mono)

graph export "volatility3.pdf", as(pdf) replace 

*****************************************************

/* ----------------------- GARCH(1,1) estimation ----------------------- */

// estimate a GARCH(1,1) model - reproduce Table 2
arch RI L.RI, arch(1) garch(1) vce(robust) distribution(t) vsquish nolog cformat(%6.4f)
estimates store mod1
predict double h, var
generate ha = sqrt(252*h)
predict double resids, res
generate stres = resids/sqrt(h)
generate stres2 = stres^2

corrgram stres2, lag(20)

// SIC says which GARCH(p,q) is the best (LOWEST SIC)

quietly {
   noisily display  "p" _col(12)  "q" _col(20) "SIC"
   noisily display  _dup(30) "-"
      forvalues p = 1/5 {
         forvalues q = 1/2 {
            arch RI, arch(1/`p') garch(1/`q')
            estat ic
            mat stats = r(S)
            noisily display `p' _col(12) `q'  _col(20) stats[1,6]
         }
      }
}

// arch RI, arch(1/2) garch(1/2) nolog vsquish cformat(%6.4f) 
// !!! FOR GARCH (p,q) via SIC


/* ----------------------- Mean reversion in vol  ----------------------- */


// is the sum of α and β significantly less than one
// estimates restore mod1
estimates restore mod1
estimates replay mod1
nlcom _b[ARCH:L.arch]+_b[ARCH:L.garch]
test _b[ARCH:L.arch]+_b[ARCH:L.garch] = 1

nlcom sqrt(252*(_b[ARCH:_cons]/(1-_b[ARCH:L.arch]-_b[ARCH:L.garch])))

// display "Annualized volatility    " sqrt(252*(_b[ARCH:_cons]/(1-_b[ARCH:L.arch]-_b[ARCH:L.garch])))


  

// estimating half-life
display "Estimated half-life   " ceil(log(0.5)/log(_b[ARCH:L.arch]+_b[ARCH:L.garch]))


capt drop resids
capt drop h
capt drop ha
predict double resids, res
predict double h, var
generate ha = sqrt(252*h)


// reproduce Figure 4
twoway (line ha Date), ///
		xlabel(, format(%tdCCYY)) xtitle("") ylabel(,angle(0)) ytitle("") ///
		title("Annualized conditional variance") ///
		name(vol, replace)  scheme(s2mono)
		
graph export "volatility4.pdf", as(pdf) replace 

*****************************************************

// estimate a TARCH(1,1) model - reproduce Table 4
// Engle and Patton say they use robust standard errors -- but do they????
// note sign change because of specification
// use t distribution
arch RI, arch(1) garch(1) tarch(1) vce(robust) distribution(t) nolog vsquish cformat(%6.4f)

// estimate GARCH(1,1)-X model === ADD VARIABLE INTO VARIANCE EQ.
// note Stata specfication is different to EVIEWS het() is exponentiated
// arch djrets, arch(1) garch(1) het(EURIBOR) vce(robust) vsquish nolog cformat(%6.4f)

*****************************************************

estimates clear
// estimate models
arch RI L.RI, arch(1) garch(2) vce(robust) distribution(t) nolog
estimates store mod1
arch RI L.RI, arch(1) garch(2) tarch(1) vce(robust) distribution(t) nolog
estimates store mod2
// arch RI, arch(1) garch(1) het(EURIBOR) vce(robust) distribution(t) nolog
// estimates store mod3

estimates table mod*, b(%6.4f) se(%6.4f) stats(ll) stfmt(%6.2f)
































*END
**# Bookmark #3




// F I N A L   V O L A T I L I T Y   M O D E L L I N G




******************   K E E P  :))  S M I L I N G   *****************************
























tssmooth ma MA_RI_10 = RI, window(5 1 5)
tssmooth ma MA_RI_1 = RI, window(1 1 1)
tssmooth ma MA_RE_10 = RE, window(5 1 5)
tssmooth ma MA_RE_1 = RE, window(1 1 1)
tssmooth ma MA_RA_10 = RA, window(5 1 5)
tssmooth ma MA_RA_1 = RA, window(1 1 1)
tssmooth ma MA_RB_10 = RB, window(5 1 5)
tssmooth ma MA_RB_1 = RB, window(1 1 1)

label variable MA_RI_10 "MA returns NASDAQ (long-term)"
label variable MA_RI_1 "MA returns NASDAQ (short-term)"
label variable MA_RE_10 "MA returns ESG ETF (long-term)"
label variable MA_RE_1 "MA returns ESG ETF (short-term)"
label variable MA_RA_10 "MA returns NVIDIA (long-term)"
label variable MA_RA_1 "MA returns NVIDIA (short-term)"
label variable MA_RB_10 "MA returns TESLA (long-term)"
label variable MA_RB_1 "MA returns TESLA (short-term)"



table () ( ) (), command(arch RI MA_RI_10 MA_RI_1, arch(1) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RI MA_RI_10 MA_RI_1, arch(1) garch(2) tarch(1) vce(robust) distribution(t) nolog) command(arch RI MA_RI_10 MA_RI_1, arch(3) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RI MA_RI_10 MA_RI_1, arch(3) garch(2) tarch(1) vce(robust) distribution(t) nolog) nformat(%9.2f) stars( _r_p 0.05 `"*"' 0.01 `"**"' 0.001 `"***"', attach(_r_b) result )
est store TGARCH_NASDAQ

collect export "K:\FEC_2025\OUTPUT\OUTPUT_TGARCH.xlsx", as(xlsx) sheet(NASDAQ) cell(A1) modify


table () ( ) (), command(arch RE MA_RE_10 MA_RE_1, arch(1) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RE MA_RE_10 MA_RE_1, arch(1) garch(2) tarch(1) vce(robust) distribution(t) nolog) command(arch RE MA_RE_10 MA_RE_1, arch(3) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RE MA_RE_10 MA_RE_1, arch(3) garch(2) tarch(1) vce(robust) distribution(t) nolog) nformat(%9.2f) stars( _r_p 0.05 `"*"' 0.01 `"**"' 0.001 `"***"', attach(_r_b) result )
est store TGARCH_ESG_ETF

collect export "K:\FEC_2025\OUTPUT\OUTPUT_TGARCH.xlsx", as(xlsx) sheet(ESG_ETF) cell(A1) modify


table () ( ) (), command(arch RA MA_RA_10 MA_RA_1, arch(1) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RA MA_RA_10 MA_RA_1, arch(1) garch(2) tarch(1) vce(robust) distribution(t) nolog) command(arch RA MA_RA_10 MA_RA_1, arch(3) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RA MA_RA_10 MA_RA_1, arch(3) garch(2) tarch(1) vce(robust) distribution(t) nolog) nformat(%9.2f) stars( _r_p 0.05 `"*"' 0.01 `"**"' 0.001 `"***"', attach(_r_b) result )
est store TGARCH_NVIDIA

collect export "K:\FEC_2025\OUTPUT\OUTPUT_TGARCH.xlsx", as(xlsx) sheet(NVIDIA) cell(A1) modify


table () ( ) (), command(arch RB MA_RB_10 MA_RB_1, arch(1) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RB MA_RB_10 MA_RB_1, arch(1) garch(2) tarch(1) vce(robust) distribution(t) nolog) command(arch RB MA_RB_10 MA_RB_1, arch(3) garch(1) tarch(1) vce(robust) distribution(t) nolog) command(arch RB MA_RB_10 MA_RB_1, arch(3) garch(2) tarch(1) vce(robust) distribution(t) nolog) nformat(%9.2f) stars( _r_p 0.05 `"*"' 0.01 `"**"' 0.001 `"***"', attach(_r_b) result )
est store TGARCH_TESLA

collect export "K:\FEC_2025\OUTPUT\OUTPUT_TGARCH.xlsx", as(xlsx) sheet(TESLA) cell(A1) modify